// --- Description: Axapta does not remove Tab,CR,LF and
// other characters below space (32), this method handles 
// both.
static str XmlTrim(str _line)
{
    #define.SPACE(32)
    int p=1, sz = strlen(_line);
    ;
 
    while(p <= sz && char2num(_line,p) <= #SPACE)
        p++;
    while(sz > p && char2num(_line,sz) <= #SPACE)
        sz--;
 
    return substr(_line,p,sz-p+1);
}
 
 
// --- Description: skip white-space even inside strings,
// needed for xml and imports.
static str XmlSkipWS(str line)
{
    #define.SPACE(32)
    str a='', ch, prev=' ';
    int j, sz=strlen(line);
    ;
    for(j=1; j <= sz; j++)
    {
        ch = substr(line,j,1);
        if(char2num(ch,1) <= #SPACE)
            ch = " "; // all chars below normal space 
                      // is considered white-space. You
                      // can change to TAB,CR,LF etc,
                      // but this works.
        if(ch != " ")
            a += ch;
        else if(prev != " ") // only add space once.
            a += " ";
        prev = ch;
 
    }
    return XmlTrim(a); // remove even possibly ending space.
}